フォト
2017年6月
        1 2 3
4 5 6 7 8 9 10
11 12 13 14 15 16 17
18 19 20 21 22 23 24
25 26 27 28 29 30  
無料ブログはココログ

« Arduinoで半角カタカナのローマ字入力 | トップページ | 豊四季 Tiny BASIC for Arduino STM32の動作テスト(4) »

2017年5月28日 (日)

豊四季 Tiny BASIC for Arduino STM32の動作テスト(3)

現在取り組んでいる「豊四季 Tiny BASIC for Arduino STM32」の動作確認の続きです。

LEDドライバ、MAX7219を使った8x8LEDドットマトリックスの制御をやってみました。

02

利用したモジュールはAliexpressで以前入手したものです。
1個150円程度で購入できます。amazonでも1個200円くらい入手出来るようです。

Free shipping! 1PCS MAX7219 dot matrix module

01

実際の動作


思っていたより、スムーズに表示出来ました。
以前IchigoJamでやった時は、1文字1秒かかりスクロール表示なんて無理な状況でした。
さすが、IchigoJamの100倍近い性能、難なく動かせました。

プログラムソース

1 'MAX7219(PB13: CLOCK, PB12: CS, PB14: DAT)
100 GOSUB "INIT"
110 M="ネコニコンバンワ!"
115 T=100
120 L=LEN(M)
130 FOR S=1 TO L
140 C=ASC(M,S)
150 GOSUB "SCROLLIN(C,T)"
160 NEXT S
170 END
200 "SCROLLIN(C,T)"
210 FOR J=0 TO 5
220 FOR K=0 TO 7
230 @(K)=(@(K)<<1)|(PEEK(C*8+FNT+K)>>(7-J))
250 NEXT K
255 GOSUB "DISP(@)"
260 WAIT T
270 NEXT J
280 RETURN
300 "DISP(@)"
310 FOR I=0 TO 7
320 R=I+1
330 V=@(I)&$FF
340 GOSUB "WRITE(R,V)"
350 NEXT I
360 RETURN
400 "INIT"
410 GPIO PB12,OUTPUT
420 GPIO PB13,OUTPUT
430 GPIO PB14,OUTPUT
440 @(0)=$0B,7,$0A,0,$0C,1,9,0,$0F,0
450 FOR I=0 TO 8 STEP 2
460 R=@(I):V=@(I+1)
470 GOSUB "WRITE(R,V)"
480 NEXT I
485 FOR I=0 TO 7:@(I)=0:NEXT I
490 RETURN
500 "WRITE(R,V)"
510 OUT PB12,LOW
520 SHIFTOUT PB14,PB13,MSB,R
530 SHIFTOUT PB14,PB13,MSB,V
540 OUT PB12,HIGH:OUT PB12,LOW
550 RETURN

プログラムの構造的には次のような感じになっています。
ボトムアップ的(下位から上位)に解説します。

・510~550行:ラベル "WRITE(R,V)"
MAX7219へのコマンド送信を行うサブルーチン
変数Rがレジスタ、変数Vがレジスタに設定する値です。
ボード上の端子PB12がCS、PB14がデータ、PB13がCLKへの出力です。
シフト操作によってR、Vの16ビットを送信しています。

ちなみに、ラベル名の"WRITE(R,V)"は単なるラベル名で、(R,V)は引数として
渡していることを分かり易くするためラベルに付けているだけです。

・400~490行:ラベル "INIT"
MAX7219の初期化処理
PB12,PB13,PB14を出力設定にしたのち、
"WRITE(R,V)"を呼び出して、440行のレジスタその設定値の内容を送信しています。
また、485行で8x8ドットの表示用バッファ(配列@(0)~@(7)を初期化しています。
レジスタ設定では輝度等の設定を行っています。

・300~360行:ラベル "DISP(@)"
8x8ドットパターンの表示処理
8x8ドットの表示用バッファ(配列@(0)~@(7))の内容をMAX7219に送信しています。
送信には"WRITE(R,V)"を呼び出しています。

・200~280行:ラベル "SCROLLIN(C,T)"
1文字単位のスクロール挿入処理
変数Cで指定した文字をスルロールしながら挿入します。
スクロールする際の1ドット毎のウェイトを変数Tで指定します。
8x8ドットの表示用バッファ(配列@(0)~@(7))に1ドットスクロールしたデータを書き込み
"DISP(@)"を呼び出して実際の表示を行っています。

文字のドットデータは、フォントデータを利用しています。
フォントデータの格納アドレスは定数FNTにて参照できます。

・100~170行:メイン処理
  下位のモジュールを使って文字列表示を行っています。
   変数Mに文字列、変数Tにスクロール速度を指定します。
   このレイアでは、MAX7219の使い方は意識しないで表示したい文字を指定して
   表示するだけです。
   
処理的に余裕がありそうなので、手持ちの四連結もMAX7219も制御出来そうです。
そのうちチャレンジ試してみよう..

« Arduinoで半角カタカナのローマ字入力 | トップページ | 豊四季 Tiny BASIC for Arduino STM32の動作テスト(4) »

arduino」カテゴリの記事

ARM」カテゴリの記事

STM32」カテゴリの記事

コメント

コメントを書く

(ウェブ上には掲載しません)

トラックバック

この記事のトラックバックURL:
http://app.cocolog-nifty.com/t/trackback/571408/65337929

この記事へのトラックバック一覧です: 豊四季 Tiny BASIC for Arduino STM32の動作テスト(3):

« Arduinoで半角カタカナのローマ字入力 | トップページ | 豊四季 Tiny BASIC for Arduino STM32の動作テスト(4) »